mirror of
https://github.com/boostorg/boost-ci.git
synced 2026-02-10 11:22:10 +00:00
c22335440c
* Deduplicate build.sh and enforce.sh * Unify Windows workflows * Factor out common linux install script * Build tests from inside BOOST_ROOT * Exit with 1 on error on windows * Remove outdated workaround for Boost.Test #144 * Fix missing unification in BDDE and mingw and add B2_CI_VERSION * Use B2_CI_VERSION to check for wanted behavior * Use other methods of getting the CPU count * Fixes #50 * Update AzP variable defintions * Zero out B2_CXXFLAGS not CXXFLAGS for bootstrap * Go back to lib folder on Windows * Move boost-root to location expected by old AzP configs
43 lines
1.3 KiB
Batchfile
43 lines
1.3 KiB
Batchfile
REM Generic install script for Windows
|
|
REM The following CI specific environment variables need to be set:
|
|
REM - SELF
|
|
REM - BOOST_CI_TARGET_BRANCH
|
|
REM - BOOST_CI_SRC_FOLDER
|
|
|
|
@ECHO ON
|
|
|
|
cd .. || EXIT /B 1
|
|
REM BOOST_BRANCH is the superproject branch we check out and build against
|
|
if "%BOOST_BRANCH%" == "" (
|
|
set BOOST_BRANCH=develop
|
|
if "%BOOST_CI_TARGET_BRANCH%" == "master" set BOOST_BRANCH=master
|
|
)
|
|
git clone -b %BOOST_BRANCH% --depth 1 https://github.com/boostorg/boost.git boost-root || EXIT /B 1
|
|
cd boost-root || EXIT /B 1
|
|
git submodule update -q --init tools/boostdep || EXIT /B 1
|
|
xcopy /s /e /q /I %BOOST_CI_SRC_FOLDER% libs\%SELF% || EXIT /B 1
|
|
REM Old configs expect boost in source folder
|
|
cd ..
|
|
move boost-root %BUILD_SOURCESDIRECTORY%\
|
|
set BOOST_ROOT=%BUILD_SOURCESDIRECTORY%\boost-root
|
|
cd %BOOST_ROOT%
|
|
|
|
python tools/boostdep/depinst/depinst.py --include benchmark --include example --include examples --include tools %DEPINST% %SELF:\=/% || EXIT /B 1
|
|
|
|
REM Bootstrap is not expecting B2_CXXFLAGS content so we zero it out for the bootstrap only
|
|
SET OLD_B2_CXXFLAGS=%B2_CXXFLAGS%
|
|
SET B2_CXXFLAGS=
|
|
cmd /c bootstrap
|
|
IF NOT %ERRORLEVEL% == 0 (
|
|
type bootstrap.log
|
|
EXIT /B 1
|
|
)
|
|
SET B2_CXXFLAGS=%OLD_B2_CXXFLAGS%
|
|
|
|
b2 headers
|
|
|
|
if DEFINED B2_CI_VERSION (
|
|
REM Go back to lib folder to allow ci\build.bat to work
|
|
cd libs\%SELF%
|
|
)
|