mirror of
https://github.com/boostorg/boost-ci.git
synced 2026-02-09 11:02:14 +00:00
883d1f414d
Allow passing of additional include paths the same way as the non-Windows builds. See `enforce.sh`
41 lines
1.5 KiB
Batchfile
41 lines
1.5 KiB
Batchfile
@ECHO OFF
|
|
setlocal enabledelayedexpansion
|
|
|
|
IF NOT DEFINED B2_CI_VERSION (
|
|
echo You need to set B2_CI_VERSION in your CI script
|
|
exit /B 1
|
|
)
|
|
|
|
IF DEFINED ADDPATH (SET "PATH=%ADDPATH%%PATH%")
|
|
|
|
SET B2_TOOLCXX=toolset=%B2_TOOLSET%
|
|
|
|
IF DEFINED B2_CXXSTD (SET B2_CXXSTD=cxxstd=%B2_CXXSTD%)
|
|
IF DEFINED B2_CXXFLAGS (SET B2_CXXFLAGS=cxxflags=%B2_CXXFLAGS%)
|
|
IF DEFINED B2_DEFINES (SET B2_DEFINES=define=%B2_DEFINES%)
|
|
IF DEFINED B2_INCLUDE (SET B2_INCLUDE=include=%B2_INCLUDE%)
|
|
IF DEFINED B2_ADDRESS_MODEL (SET B2_ADDRESS_MODEL=address-model=%B2_ADDRESS_MODEL%)
|
|
IF DEFINED B2_LINK (SET B2_LINK=link=%B2_LINK%)
|
|
IF DEFINED B2_VARIANT (SET B2_VARIANT=variant=%B2_VARIANT%)
|
|
|
|
set SELF_S=%SELF:\=/%
|
|
IF NOT DEFINED B2_TARGETS (SET B2_TARGETS=libs/!SELF_S!/test)
|
|
IF NOT DEFINED B2_JOBS (SET B2_JOBS=3)
|
|
|
|
REM clang-win requires to use the linker for the manifest
|
|
IF "%B2_TOOLSET%" == "clang-win" (
|
|
IF NOT DEFINED B2_FLAGS (SET B2_FLAGS=embed-manifest-via=linker)
|
|
ELSE (SET B2_FLAGS=embed-manifest-via=linker %B2_FLAGS%)
|
|
)
|
|
|
|
cd %BOOST_ROOT%
|
|
|
|
IF DEFINED SCRIPT (
|
|
call libs\%SELF%\%SCRIPT%
|
|
) ELSE (
|
|
REM Echo the complete build command to the build log
|
|
ECHO b2 --abbreviate-paths %B2_TARGETS% %B2_TOOLCXX% %B2_CXXSTD% %B2_CXXFLAGS% %B2_DEFINES% %B2_INCLUDE% %B2_THREADING% %B2_ADDRESS_MODEL% %B2_LINK% %B2_VARIANT% -j%B2_JOBS% %B2_FLAGS%
|
|
REM Now go build...
|
|
b2 --abbreviate-paths %B2_TARGETS% %B2_TOOLCXX% %B2_CXXSTD% %B2_CXXFLAGS% %B2_DEFINES% %B2_INCLUDE% %B2_THREADING% %B2_ADDRESS_MODEL% %B2_LINK% %B2_VARIANT% -j%B2_JOBS% %B2_FLAGS%
|
|
)
|